Noções básicas e primeiros passos de Programação

Como um programa armazena as informações?

Quando você cria uma variável, você diz para o computador:

Computador você pode guardar alguma informação nesta caixa, ok?

Conheça os tipos de variáveis do Portugol Studio:

Se você não criar a sua variável seu computador não saberá que existe uma “caixa” para guardar algo. Existem modelos de “caixas” diferentes, você não pode guardar o nome do tipo cadeia no salario tipo real.  Veja exemplo de declaração de variáveis

O programador pode trocar o valor da variável, note no programa acima, o valor inicial foi trocado por um valor maior, é como colocar outra coisa dentro na “caixa”

Eu posso dividir meu programa em diversas partes menores?

Vamos ensinar como criar um menu utilizando uma função:

Escreva o código exemplo da função chama_menu() abaixo da função inicio(), depois coloque o nome da função chama_menu() para ser chamada dentro da função inicio() e faça um teste.

Você verá o resultado abaixo:

Boa sorte!

Abaixo o código pronto do desafio, não copie o código, tente fazer sozinho. Você será um grande programador se praticar bastante lógica de programação.

programa {

  inteiro votos_bonito = 0
  inteiro votos_feio = 0
  cadeia nome

  funcao inicio() {

    escreva("Nome do participante: ")
    leia(nome)

    chama_menu()    
  
  }

  funcao chama_menu()
  {
    inteiro opcao
    escreva("\n Escolha Uma Opção:")
    escreva("\n 1 - Vote")
    escreva("\n 2 - Resultado da votação")
    escreva("\n Opção: ")
    
    leia(opcao)
    limpa()

    escolha(opcao)
    {
      caso 1:
      vote()
      pare
      caso 2:
      resultado_votacao()
      pare
      caso contrario:
      escreva("Opção Inválida!")
      chama_menu()
    }

  }

  funcao vote()
  {
    inteiro opcao
    escreva("\n Você acha o ", nome, " bonito? Vote:")
    escreva("\n 1 - Bonito(a)")
    escreva("\n 2 - Feio(a)")
    escreva("\n 3 - Retorne ao menu principal")  
    escreva("\n Opção: ")
    
    leia(opcao)
    limpa()

    escolha(opcao)
    {
      caso 1:
      votos_bonito = votos_bonito + 1
      vote()
      pare
      caso 2:
      votos_feio = votos_feio + 1
      vote()
      pare
      caso 3:
      chama_menu()
      pare
      caso contrario:
      escreva("Opção Inválida!")
      chama_menu()
    }

  }

  funcao resultado_votacao()
  {
    escreva("\n", votos_bonito, " pessoas votaram Bonito para o ", nome)
    escreva("\n", votos_feio, " pessoas votaram Feio para o ",nome)
  }


}