Operadores de atribuição
Antes de tudo precisamos conhecer este conceito: Operadores de Atribuição.
É utilizado para definir o valor inicial ou sobrescrever o valor de uma variável. Em seu uso, o operando à esquerda representa a variável para a qual desejamos atribuir o valor informado à direita.
Exemplo de uso:
Operadores Aritméticos
Use operadores aritméticos para realizar cálculos matemáticos em dados numéricos.
Em Portugol Studio , nós podemos executar operações aritméticas usando variáveis e constantes. Algumas operações mais comuns são:
+ adição
– subtração
* multiplicação
/ divisão
Vamos ver um exemplo na prática utilizando o Portugol Studio!
Copie o código abaixo e execute o programa no Portugol Studio utilizando o modo passo-a-passo (indicado na seta amarela), na programação é chamado modo DEBUG.
Utilizando o modo DEBUG lhe ajudará no entendimento do código programado.
programa
{
funcao inicio()
{
real a, b, soma, sub, mult, div
escreva("Digite o primeiro número: ")
leia(a)
escreva("Digite o segundo número: ")
leia(b)
soma = a + b // Soma os dois valores
escreva("\nA soma dos números é igual a: ", soma)
sub = a - b // Subtrai os dois valores
escreva("\nA subtração dos números é igual a: ", sub)
mult = a * b // Multiplica os dois valores
escreva("\nA multiplicação dos números é igual a: ", mult)
div = a / b // Divide os dois valores
escreva("\nA divisão dos números é igual a: ", div, "\n")
}
}
E qual a ordem correta das operações matemáticas?
Há muito tempo atrás, os matemáticos decidiram qual deveria ser a ordem pela qual as operações deveriam ser executadas. Não tem nada a ver com lógica é apenas uma convenção. Algumas pessoas decidiram adotar essa ordem, que se generalizou e foi seguida por todos. A partir daqui tornou-se uma regra matemática, e respeitar essa ordem tornou-se obrigatório, ficando assim mais fácil a comunicação entre matemáticos e não matemáticos.
Posto isto, eis então a ordem correta para executar as operações matemáticas:
- 1º Parêntesis;
- 2º Multiplicações e Divisões; (da esquerda para a direita);
- 3º Somas e Subtrações. (da esquerda para a direita).
Para entender melhor e fixar o entendimento na cabeça, vamos praticar!
Copie código do programa abaixo e execute-o para ver o resultado, mas utilize a calculadora do computador para chegar no resultado de cada operação para ter melhor entendimento da regra.
programa
{
funcao inicio()
{
real resultado
// Neste exemplo, a operação de multiplicação (*) será executada primeiro
resultado = 5.0 + 4.0 * 2.0
escreva("Operação: 5 + 4 * 2 = ", resultado)
// Neste exemplo, a operação de soma (+) será executada primeiro
resultado = (5.0 + 4.0) * 2.0
escreva("\nOperação: (5 + 4) * 2 = ", resultado)
/*
* Neste exemplo, a operação de divisão (/) será executada primeiro,
* seguida pela operação de multiplicação (*). Por último, será
* executada a operação de soma (+)
*/
resultado = 1.0 + 2.0 / 3.0 * 4.0
escreva("\nOperação: 1 + 2 / 3 * 4 = ", resultado)
/*
* Neste exemplo, a operação de soma (+) será executada primeiro,
* seguida pela operação de multiplicação (*). Por último, será
* executada a operação de divisão (/).
*/
resultado = (1.0 + 2.0) / (3.0 * 4.0)
escreva("\nOperação: (1 + 2) / (3 * 4) = ", resultado, "\n")
}
}Para abrir a calculadora, na busca do Windows digite CALC, pode variar conforme versão do Windows, exemplo:
Conseguiu chegar no resultado com a calculadora? Espero que sim, é muito importante você ter esse conhecimento para virar um programador de sucesso.
Operadores de incremento e decremento
Os operadores de incremento e decremento também são bastante utilizados. Basicamente temos dois deles:++ e —, os quais podem ser declarados antes ou depois da variável e incrementam ou decrementam em 1 o valor da variável.
Copie código do programa abaixo e execute-o para praticar.
programa
{
funcao inicio()
{
inteiro a = 2
inteiro b= 2
a++
b--
escreva("Incremeto: ",a)
escreva("\ndecremento: ",b)
}
}
Operadores Relacionais
Vamos imaginar que você precise verificar se um número digitado pelo usuário é positivo ou negativo. Como poderíamos verificar isto? Através de uma operação relacional.
As operações relacionais também são nossas conhecidas da Matemática. Em algoritmos, os operadores relacionais são importantes, pois permitem realizar comparações que terão como resultado um valor lógico (verdadeiro ou falso).
Os símbolos que usamos para os operadores também mudam um pouco em relação ao que usamos no papel. Os símbolos para diferente, maior ou igual e menor ou igual mudam pois não existem nos teclados convencionais. A tabela a seguir mostra todas as operações relacionais e os símbolos que o Portugol utiliza.
Em geral, as operações relacionais são utilizadas em conjunto com as Estruturas de Controle.
Veja as sintaxes mais utilizadas em conjunto com os operadores relacionais:
A sintaxe SE, é uma das mais utilizados na programação:
Vamos praticar, copie o código abaixo e execute o programa no modo de DEBUG (passo-a-passo) para melhor compreensão.
programa
{
funcao inicio()
{
// Declaração de variaveis
inteiro a, b
//informe a e b
escreva("Infome numero de a: ")
leia(a)
escreva("\nInfome numero de b: ")
leia(b)
//Comparação entre valor A e B utilizando o operador maior que
se(a > b){
escreva("\nA é maior que B")
}
//Comparação entre A e B utilizando o operador igual a
se(a == b){
escreva("\nA é igual a B")
}
//Comparação entre A e B utilizando o operador maior ou igual a
se(a < b){
escreva("\nA é menor a B")
}
}
}
A sintaxe para é uma sequência de repetição até conseguir atender a condição, no exemplo abaixo a variável i começa com 0, depois enquanto i < 5 ficará na sequencia de repetição, muito conhecido como LOOP na programação, por último é feito o incremento na variável i.
Vamos praticar mais, copie o código abaixo e execute o programa no modo de DEBUG (passo-a-passo) para melhor compreensão.
programa {
funcao inicio() {
inteiro repeticao
escreva("Informe quantas vezes você quer repetir: ")
leia(repeticao)
para (inteiro i = 1; i <= repeticao; i++)
{
//Codigo a ser executado enquanto a condição for satisfeita.
escreva("\nEstou passando por aqui no i: ",i)
}
}
}A sintaxe faca (“Faça”) também ficará no fluxo de repetição até atender a condição enquanto 6 < 2.
Vamos praticar mais um pouco, copie o código abaixo e execute o programa no modo de DEBUG (passo-a-passo) para melhor compreensão.
programa {
funcao inicio() {
inteiro repeticao
inteiro i = 1
escreva("Informe quantas vezes você quer repetir: ")
leia(repeticao)
faca
{
//Executa os comandos pelo menos uma vez, e continua executando enquanto a condição for verdadeira
escreva("\nEstou passando por aqui no i: ",i)
i++
} enquanto (i <= repeticao)
}
}Operadores de Caracteres
Operador de concatenação de strings (isto é, cadeias de caracteres), quando usado com dois valores (variáveis ou constantes) do tipo “caractere”. Por exemplo: “Rio ” + ” de Janeiro” = “Rio de Janeiro”.
Tente fazer utilizando o comando escreva do Portugol Studio.
Operadores Lógicos
Os operadores lógicos representam o recurso que nos permite criar expressões lógicas maiores a partir da junção de duas ou mais expressões. Para isso, aplicamos as operações lógicas E e OU.
Vamos praticar um pouco mais, copie o código e execute-o.
programa
{
funcao inicio()
{
inteiro hora
escreva ("Digite a hora: ")
leia (hora)
se (hora >= 6 e hora <= 18)
{
escreva ("É dia")
}
senao
{
escreva ("É noite")
}
}
} Agora que você aprendeu diversos conceitos, vamos fazer os exercícios na plataforma Martec.
Acesse entre com seu login e senha execute todos os exercícios da disciplina:
Desvios condicionais, fazendo seu programa tomar decisões!
O que é uma FUNÇÃO na programação (e como utilizar)?
Noções básicas e primeiros passos de Programação